spiegel-keyman/android/KMEA/app/build.gradle

apply plugin: 'com.android.library'

android {
    compileSdkVersion 25
    buildToolsVersion "26.0.2"

    defaultConfig {
        minSdkVersion 15
        targetSdkVersion 25

        if (project.hasProperty("build.number")) {
            versionCode project.ext['build_counter'] as Integer // Because TeamCity does not bubble build.counter into system properties...
            versionName "${project.ext['build.number']}"
        } else {
            versionCode 100
            versionName '0.0-beta'
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
    }

    testOptions {
        unitTests {
            // Allows use of a simulated Android API for tests.  (Thanks, roboelectric!)
            includeAndroidResources = true
        }
        unitTests.all {
            testLogging {
                // May also add "passed", "skipped".
                events "failed"//, "standardOut", "standardError" if we want them to show in builds.
                outputs.upToDateWhen {false}
                //showStandardStreams = true // If we want test console log output to show during builds.
            }
            workingDir = "../" // Defaults to the `app` subdirectory, which is different from Android Studio's default.
        }
    }
}

dependencies {
    implementation 'com.android.support:support-v4:25.4.0'
    implementation 'commons-io:commons-io:2.6'
    testImplementation 'junit:junit:4.12'
    testImplementation "org.robolectric:robolectric:3.5.1"
}